update

scripts/skills.gd

@@ -0,0 +1,62 @@
+class_name Skills
+## Skilltree: Erfahrung sind die verdienten Münzen, je Level ein Skillpunkt, Punkte kaufen Stufen
+## der Skills in drei Ästen. Münzen kaufen keine Punkte.
+
+const BRANCHES: Array[String] = ["Sammeln", "Wirtschaft", "Kampf"]
+## id -> Name, Ast, Höchststufe, Text.
+const SKILLS := {
+    "packglueck": {"name": "Packglück", "branch": "Sammeln", "max": 3, "text": "Seltenere Karten in Boostern"},
+    "staub": {"name": "Staubsammler", "branch": "Sammeln", "max": 3, "text": "Mehr Staub aus Doppelten und Zerlegen"},
+    "muenzen": {"name": "Münzsegen", "branch": "Wirtschaft", "max": 3, "text": "Mehr Münzen nach jedem Kampf"},
+    "packpreis": {"name": "Händler", "branch": "Wirtschaft", "max": 2, "text": "Booster werden billiger"},
+    "gratisziehen": {"name": "Freies Ziehen", "branch": "Kampf", "max": 1, "text": "Das zweite Ziehen je Zug ist auch gratis"},
+    "startmana": {"name": "Starker Start", "branch": "Kampf", "max": 1, "text": "Mehr Mana im ersten Zug"},
+}
+## Kampfskills geben ein Merkmal (Game.PERKS) im Kampf.
+const PERK_OF := {"gratisziehen": "ziehen_gratis", "startmana": "start_energie"}
+## Packglück je Stufe: Common gibt ab, die höheren Stufen gewinnen.
+const LUCK_SHIFT := {"Common": -8.0, "Rare": 3.0, "Super Rare": 2.0, "Ultra Rare": 2.0, "Ultimate Rare": 1.0}
+
+
+## Erfahrung, die Level n verlangt: 100, 300, 600, 1000, 1500 … (50 · n · (n + 1)).
+static func xp_for_level(n: int) -> int:
+    return 50 * n * (n + 1)
+
+
+## Level zu einer Erfahrung.
+static func level_for(xp: int) -> int:
+    var n := 0
+    while xp >= xp_for_level(n + 1):
+        n += 1
+    return n
+
+
+static func in_branch(branch: String) -> Array:
+    return SKILLS.keys().filter(func(id): return SKILLS[id].branch == branch)
+
+
+## Boosterchancen je Stufe (Reihenfolge Cards.RARITIES) mit Packglück luck.
+static func pack_weights(luck: int) -> PackedFloat32Array:
+    var out := PackedFloat32Array()
+    for rar in Cards.RARITIES:
+        out.append(float(Profile.RARITY_WEIGHTS[rar]) + luck * float(LUCK_SHIFT[rar]))
+    return out
+
+
+## Konkrete Wirkung eines Skills auf einer Stufe, als Text.
+static func effect(id: String, rank: int) -> String:
+    match id:
+        "packglueck":
+            var w := pack_weights(rank)
+            return TranslationServer.translate("Chancen %d/%d/%d/%d/%d %%") % [int(w[0]), int(w[1]), int(w[2]), int(w[3]), int(w[4])]
+        "staub":
+            return TranslationServer.translate("+%d %% Staub") % (25 * rank)
+        "muenzen":
+            return TranslationServer.translate("+%d %% Münzen") % (10 * rank)
+        "packpreis":
+            return TranslationServer.translate("Neutral %d, Element %d Münzen") % [roundi(Profile.BOOSTER_COST * (1.0 - 0.1 * rank)), roundi(Profile.ELEMENT_BOOSTER_COST * (1.0 - 0.1 * rank))]
+        "gratisziehen":
+            return TranslationServer.translate("zwei Karten je Zug gratis" if rank > 0 else "eine Karte je Zug gratis")
+        "startmana":
+            return TranslationServer.translate("erster Zug: %d Mana") % (Game.START_MANA + (2 if rank > 0 else 0))
+    return ""