class_name CardGrid
extends ScrollContainer
## Scrollbares Kartenraster.

signal card_clicked(card: Cards.Card)

const COLS := 6
const CW := 118
const CH := 165
const GAP := 10

var grid: GridContainer


func _init(rect: Rect2) -> void:
    position = rect.position
    size = rect.size
    horizontal_scroll_mode = ScrollContainer.SCROLL_MODE_DISABLED
    follow_focus = true  # Gamepad: der fokussierten Karte hinterherscrollen
    grid = GridContainer.new()
    grid.columns = COLS
    grid.add_theme_constant_override("h_separation", GAP)
    grid.add_theme_constant_override("v_separation", GAP)
    add_child(grid)


## cards: Karten; rarity_fn(card) -> String: die Stufe, die die Karte zeigt (Optik)
func fill(cards: Array, rarity_fn: Callable) -> void:
    Style.clear(grid)
    for c in cards:
        var cell := Control.new()
        cell.custom_minimum_size = Vector2(CW, CH)
        cell.mouse_filter = Control.MOUSE_FILTER_IGNORE
        var v := CardView.new(c, Vector2(CW, CH), true, rarity_fn.call(c))
        v.clicked.connect(func(_view): card_clicked.emit(c))
        cell.add_child(v)
        grid.add_child(cell)


func views() -> Array:
    var out := []
    for cell in grid.get_children():
        for v in cell.get_children():
            if v is CardView:
                out.append(v)
    return out