update

scripts/enemy/enemy_aggro.gd

@@ -0,0 +1,51 @@
+extends Node
+
+const AGGRO_DECAY := 1.0
+var aggro_table: Dictionary = {}
+
+@onready var enemy: CharacterBody3D = get_parent()
+
+func _ready() -> void:
+  EventBus.damage_dealt.connect(_on_damage_dealt)
+  EventBus.entity_died.connect(_on_entity_died)
+
+func _process(delta: float) -> void:
+  for player in aggro_table.keys():
+    aggro_table[player] -= AGGRO_DECAY * delta
+    if aggro_table[player] <= 0:
+      aggro_table.erase(player)
+  var top_target: Node = _get_top_target()
+  if top_target and top_target != enemy.target:
+    enemy.target = top_target
+    if enemy.state == enemy.State.IDLE or enemy.state == enemy.State.RETURN:
+      enemy.state = enemy.State.CHASE
+
+func _on_damage_dealt(attacker: Node, target: Node, amount: float) -> void:
+  if target != enemy:
+    return
+  var multiplier := 1.0
+  var player_class: Node = attacker.get_node_or_null("PlayerClass")
+  if player_class and player_class.current_class == 0:
+    multiplier = 2.0
+  add_aggro(attacker, amount * multiplier)
+
+func _on_entity_died(entity: Node) -> void:
+  aggro_table.erase(entity)
+
+func add_aggro(player: Node, amount: float) -> void:
+  if player in aggro_table:
+    aggro_table[player] += amount
+  else:
+    aggro_table[player] = amount
+
+func _get_top_target() -> Node:
+  var top: Node = null
+  var top_val := 0.0
+  for player in aggro_table:
+    if is_instance_valid(player) and aggro_table[player] > top_val:
+      top_val = aggro_table[player]
+      top = player
+  return top
+
+func has_aggro_on(player: Node) -> bool:
+  return _get_top_target() == player