extends Node

const GCD_TIME := 0.5

@onready var player: CharacterBody3D = get_parent()
@onready var targeting: Node = get_parent().get_node("Targeting")
@onready var player_class: Node = get_parent().get_node("PlayerClass")

var abilities: Array = []
var cooldowns: Array[float] = [0.0, 0.0, 0.0, 0.0, 0.0]
var max_cooldowns: Array[float] = [0.0, 0.0, 0.0, 0.0, 0.0]
var gcd_timer := 0.0

func _ready() -> void:
  _load_abilities()
  EventBus.class_changed.connect(_on_class_changed)

func _process(delta: float) -> void:
  if gcd_timer > 0:
    gcd_timer -= delta
  for i in range(cooldowns.size()):
    if cooldowns[i] > 0:
      cooldowns[i] -= delta
  EventBus.cooldown_tick.emit(cooldowns, max_cooldowns, gcd_timer)

func _load_abilities() -> void:
  var ability_set: AbilitySet = player_class.get_ability_set()
  if ability_set:
    abilities = ability_set.abilities
  else:
    abilities = []
  cooldowns = [0.0, 0.0, 0.0, 0.0, 0.0]
  max_cooldowns = [0.0, 0.0, 0.0, 0.0, 0.0]
  gcd_timer = 0.0

func _unhandled_input(event: InputEvent) -> void:
  for i in range(min(abilities.size(), 5)):
    if event.is_action_pressed("ability_%s" % (i + 1)) and abilities[i]:
      if abilities[i].type == Ability.Type.PASSIVE:
        return
      if cooldowns[i] > 0:
        return
      if abilities[i].uses_gcd and gcd_timer > 0:
        return
      var success: bool = abilities[i].execute(player, targeting)
      if not success:
        return
      var ability_cd: float = abilities[i].cooldown
      var gcd_cd: float = GCD_TIME if abilities[i].uses_gcd else 0.0
      cooldowns[i] = ability_cd
      max_cooldowns[i] = max(ability_cd, gcd_cd)
      if abilities[i].uses_gcd:
        gcd_timer = GCD_TIME
      return

func apply_passive(base_damage: float) -> float:
  for ability in abilities:
    if ability and ability.type == Ability.Type.PASSIVE:
      return base_damage * (1.0 + ability.damage / 100.0)
  return base_damage

func _on_class_changed(_player: Node, _class_type: int) -> void:
  _load_abilities()