extends Node

const AGGRO_DECAY := 1.0
const PORTAL_RADIUS := 10.0
var aggro_table: Dictionary = {}
var seconds_outside := 0.0

@onready var enemy: CharacterBody3D = get_parent()

func _ready() -> void:
  EventBus.damage_dealt.connect(_on_damage_dealt)
  EventBus.entity_died.connect(_on_entity_died)
  EventBus.heal_requested.connect(_on_heal_requested)

func _process(delta: float) -> void:
  var outside_portal := false
  if enemy.portal and is_instance_valid(enemy.portal):
    var dist_to_portal: float = enemy.global_position.distance_to(enemy.portal.global_position)
    if dist_to_portal > PORTAL_RADIUS:
      outside_portal = true
      seconds_outside += delta
    else:
      seconds_outside = 0.0

  for player in aggro_table.keys():
    var decay: float = AGGRO_DECAY * delta
    if outside_portal:
      var bonus_decay: float = aggro_table[player] * 0.01 * pow(2, seconds_outside) * delta
      decay += bonus_decay
    aggro_table[player] -= decay
    # Im Portal-Radius: Aggro bleibt bei mindestens 1
    if not outside_portal and enemy.portal and is_instance_valid(player):
      var player_dist: float = player.global_position.distance_to(enemy.portal.global_position)
      if player_dist <= PORTAL_RADIUS and aggro_table[player] < 1.0:
        aggro_table[player] = 1.0
    if aggro_table[player] <= 0:
      aggro_table.erase(player)

  var top_target: Node = _get_top_target()
  if top_target and top_target != enemy.target:
    enemy.target = top_target
    if enemy.state == enemy.State.IDLE or enemy.state == enemy.State.RETURN:
      enemy.state = enemy.State.CHASE
  elif not top_target and enemy.state != enemy.State.IDLE and enemy.state != enemy.State.RETURN:
    enemy.target = null
    enemy.state = enemy.State.RETURN

func _on_damage_dealt(attacker: Node, target: Node, amount: float) -> void:
  if target != enemy:
    return
  var multiplier := 1.0
  var role: Node = attacker.get_node_or_null("Role")
  if role and role.current_role == 0:
    multiplier = 2.0
  add_aggro(attacker, amount * multiplier)

func _on_heal_requested(healer: Node, _target: Node, amount: float) -> void:
  if not healer.is_in_group("player"):
    return
  if healer in aggro_table:
    add_aggro(healer, amount * 0.5)

func _on_entity_died(entity: Node) -> void:
  aggro_table.erase(entity)

func add_aggro(player: Node, amount: float) -> void:
  if player in aggro_table:
    aggro_table[player] += amount
  else:
    aggro_table[player] = amount

func _get_top_target() -> Node:
  var top: Node = null
  var top_val := 0.0
  for player in aggro_table:
    if is_instance_valid(player) and aggro_table[player] > top_val:
      top_val = aggro_table[player]
      top = player
  return top

func has_aggro_on(player: Node) -> bool:
  return _get_top_target() == player