extends Node

@export var stats: EntityStats
var max_shield: float
var regen_delay: float
var regen_time: float
var current_shield: float
var regen_timer := 0.0

func _ready() -> void:
  max_shield = stats.max_shield
  regen_delay = stats.shield_regen_delay
  regen_time = stats.shield_regen_time
  current_shield = max_shield

func _process(delta: float) -> void:
  if max_shield <= 0:
    return
  if current_shield < max_shield:
    regen_timer += delta
    if regen_timer >= regen_delay:
      current_shield += (max_shield / regen_time) * delta
      if current_shield >= max_shield:
        current_shield = max_shield
        EventBus.shield_regenerated.emit(get_parent())
      EventBus.shield_changed.emit(get_parent(), current_shield, max_shield)

func absorb(amount: float) -> float:
  if current_shield <= 0:
    return amount
  regen_timer = 0.0
  var absorbed: float = min(amount, current_shield)
  current_shield -= absorbed
  if current_shield <= 0:
    EventBus.shield_broken.emit(get_parent())
  EventBus.shield_changed.emit(get_parent(), current_shield, max_shield)
  return amount - absorbed