mmo/systems/hud_system.gd

extends Node

const GCD_TIME := 0.5
const ICON_SIZE := 20
const FONT_SIZE := 14
const BORDER_WIDTH := 2
const MARGIN := 2

var ability_labels: Array[String] = ["1", "2", "3", "4", "P"]
var effect_container: HBoxContainer = null

func _ready() -> void:
  EventBus.health_changed.connect(_on_health_changed)
  EventBus.shield_changed.connect(_on_shield_changed)
  EventBus.entity_died.connect(_on_entity_died)
  EventBus.player_respawned.connect(_on_player_respawned)
  EventBus.respawn_tick.connect(_on_respawn_tick)
  EventBus.role_changed.connect(_on_role_changed)
  EventBus.cooldown_tick.connect(_on_cooldown_tick)
  EventBus.effect_applied.connect(_on_effect_applied)
  EventBus.effect_expired.connect(_on_effect_expired)
  _init_hud.call_deferred()

func _init_hud() -> void:
  var hud: CanvasLayer = _get_hud()
  if not hud:
    return
  hud.get_node("RespawnTimer").visible = false
  effect_container = HBoxContainer.new()
  effect_container.name = "EffectContainer"
  effect_container.position = Vector2(10, 60)
  effect_container.add_theme_constant_override("separation", 3)
  hud.add_child(effect_container)

func _on_health_changed(entity: Node, current: float, max_val: float) -> void:
  if entity != PlayerData:
    return
  var hud: CanvasLayer = _get_hud()
  if not hud:
    return
  var bar: ProgressBar = hud.get_node("HealthBar")
  bar.max_value = max_val
  bar.value = current
  hud.get_node("HealthBar/HealthLabel").text = "%d/%d" % [current, max_val]

func _on_shield_changed(entity: Node, current: float, max_val: float) -> void:
  if entity != PlayerData:
    return
  var hud: CanvasLayer = _get_hud()
  if not hud:
    return
  var bar: ProgressBar = hud.get_node("ShieldBar")
  bar.max_value = max_val
  bar.value = current
  hud.get_node("ShieldBar/ShieldLabel").text = "%d/%d" % [current, max_val]

func _on_entity_died(entity: Node) -> void:
  if entity != PlayerData:
    return
  var hud: CanvasLayer = _get_hud()
  if hud:
    hud.get_node("RespawnTimer").visible = true

func _on_player_respawned(_player: Node) -> void:
  var hud: CanvasLayer = _get_hud()
  if hud:
    hud.get_node("RespawnTimer").visible = false

func _on_respawn_tick(timer: float) -> void:
  var hud: CanvasLayer = _get_hud()
  if hud:
    hud.get_node("RespawnTimer").text = str(ceil(timer))

func _on_role_changed(_player: Node, role_type: int) -> void:
  var hud: CanvasLayer = _get_hud()
  if not hud:
    return
  var icon: Label = hud.get_node("AbilityBar/ClassIcon/Label")
  match role_type:
    0: icon.text = "T"
    1: icon.text = "D"
    2: icon.text = "H"

func _on_cooldown_tick(cooldowns: Array, max_cooldowns: Array, gcd_timer: float) -> void:
  var hud: CanvasLayer = _get_hud()
  if not hud:
    return
  var panels: Array = [
    hud.get_node("AbilityBar/Ability1"),
    hud.get_node("AbilityBar/Ability2"),
    hud.get_node("AbilityBar/Ability3"),
    hud.get_node("AbilityBar/Ability4"),
    hud.get_node("AbilityBar/Ability5"),
  ]
  for i in range(min(panels.size(), cooldowns.size())):
    var panel: Panel = panels[i]
    var label: Label = panel.get_node("Label")
    var overlay: ColorRect = panel.get_node("CooldownOverlay")
    var cd: float = cooldowns[i]
    var gcd: float = gcd_timer if i != 2 and i != 4 else 0.0
    var active_cd: float = max(cd, gcd)
    var max_cd: float = max_cooldowns[i] if max_cooldowns[i] > 0 else GCD_TIME
    if active_cd > 0:
      var ratio: float = clamp(active_cd / max_cd, 0.0, 1.0)
      overlay.visible = true
      overlay.anchor_bottom = ratio
      label.text = str(ceil(active_cd))
    else:
      overlay.visible = false
      label.text = ability_labels[i]

func _on_effect_applied(target: Node, effect: Effect) -> void:
  if target != PlayerData:
    return
  if effect_container:
    _add_icon(effect)

func _on_effect_expired(target: Node, effect: Effect) -> void:
  if target != PlayerData:
    return
  if effect_container:
    _remove_icon(effect)

func _add_icon(effect: Effect) -> void:
  var panel := PanelContainer.new()
  var style := StyleBoxFlat.new()
  match effect.type:
    Effect.Type.AURA:
      style.bg_color = Color(0.15, 0.15, 0.3, 1)
      style.border_color = Color(0.3, 0.5, 1.0, 1)
    Effect.Type.BUFF:
      style.bg_color = Color(0.15, 0.3, 0.15, 1)
      style.border_color = Color(0.3, 1.0, 0.3, 1)
    Effect.Type.DEBUFF:
      style.bg_color = Color(0.3, 0.15, 0.15, 1)
      style.border_color = Color(1.0, 0.3, 0.3, 1)
  style.set_border_width_all(BORDER_WIDTH)
  style.set_content_margin_all(MARGIN)
  panel.add_theme_stylebox_override("panel", style)
  var label := Label.new()
  label.text = effect.effect_name.left(1)
  label.horizontal_alignment = HORIZONTAL_ALIGNMENT_CENTER
  label.vertical_alignment = VERTICAL_ALIGNMENT_CENTER
  label.add_theme_font_size_override("font_size", FONT_SIZE)
  label.add_theme_color_override("font_color", Color.WHITE)
  label.custom_minimum_size = Vector2(ICON_SIZE, ICON_SIZE)
  panel.add_child(label)
  panel.custom_minimum_size = Vector2(ICON_SIZE + BORDER_WIDTH * 2, ICON_SIZE + BORDER_WIDTH * 2)
  panel.set_meta("effect_type", effect.type)
  panel.set_meta("effect_name", effect.effect_name)
  var insert_idx := 0
  for child in effect_container.get_children():
    if child.has_meta("effect_type") and child.get_meta("effect_type") <= effect.type:
      insert_idx += 1
    else:
      break
  effect_container.add_child(panel)
  effect_container.move_child(panel, insert_idx)

func _remove_icon(effect: Effect) -> void:
  for child in effect_container.get_children():
    if child.has_meta("effect_type") and child.has_meta("effect_name"):
      if child.get_meta("effect_type") == effect.type and child.get_meta("effect_name") == effect.effect_name:
        child.queue_free()
        return

func _get_hud() -> CanvasLayer:
  return get_tree().get_first_node_in_group("hud") as CanvasLayer